Crear factura electrónica de ARCA en Visual Fox Pro
Con pocas líneas de código
Si es tu primera vez conectándote con la facturación electrónica de ARCA, te recomiendo leer esta guía básica sobre su funcionamiento general.
Conectar tu sistema con la facturación electrónica de ARCA
Guía paso a paso
El primer paso para crear una factura electrónica de ARCA en Visual Fox Pro es obtener el Código de Autorización Electrónico o CAE.
Esto lo vamos a hacer utilizando Afip SDK que nos permite conectarnos a los web services de ARCA sin complicarnos con el uso de SOAP y la autenticación.
Ademas, vamos a usar https://github.com/sait/vfpjson/blob/master/json.prg para trabajar con JSON.
SET PROCEDURE TO "path\al\archivo\json.prg" ADDITIVE
Obtener la autorización
Lo primero que tenemos hacer es obtener el “Token authorization”, que seria la autorización en ARCA.
Para usar los web services de ARCA, se requiere un certificado digital, con Afip SDK puedes integrarte en modo desarrollo usando el CUIT 20409378472 sin necesidad de obtener un certificado, para poder integrarte lo más rápido posible.
Te dejo este enlace por si luego quieres usar tu propio certificado para desarrollo.
Debemos ejecutar una solicitud POST al endpoint
https://app.afipsdk.com/api/v1/afip/auth
LOCAL loHttp, loResponse, lcJson, lcAuthUrl, loAuthData, loAuthResponse
loHttp = CREATEOBJECT("Msxml2.XMLHTTP")
lcAuthUrl = "https://app.afipsdk.com/api/v1/afip/auth"
loAuthData = '{' + ;
'"environment": "dev",' + ;
'"tax_id": "20409378472",' + ;
'"wsid": "wsfe"' + ;
'}'
loHttp.Open("POST", lcAuthUrl, .F.)
loHttp.setRequestHeader("Content-Type", "application/json")
loHttp.Send(loAuthData)
IF loHttp.Status <> 200
? "Error en la autorizacion: " + STR(loHttp.Status)
RETURN
ENDIF
loResponse = loHttp.responseText
loAuthResponse = json_decode(loResponse)
lcToken = loAuthResponse._token
lcSign = loAuthResponse._sign
? "Token: " + lcToken
? "Sign: " + lcSign
Ahora tenemos token y sign que nos dio ARCA para usar el web service. No es necesario que lo guardemos, Afip SDK se encarga de esto por nosotros, debemos solicitarlo antes de cada llamada a los métodos del web service.
Crear la factura
Vamos a crear una Factura B por un importe de $121. En nuestro código, añadimos la siguiente lógica:
Debemos ejecutar una solicitud POST al endpoint
https://app.afipsdk.com/api/v1/afip/requests
LOCAL loHttp, loResponse, lcInvoiceUrl, loInvoiceData, loInvoiceResponse
loHttp = CREATEOBJECT("Msxml2.XMLHTTP")
lcNextVoucherNumber = 1
lcInvoiceUrl = "https://app.afipsdk.com/api/v1/afip/requests"
loInvoiceData = '{' + ;
'"environment": "dev",' + ;
'"method": "FECAESolicitar",' + ;
'"wsid": "wsfe",' + ;
'"params": {' + ;
' "Auth": {' + ;
' "Token": "' + lcToken + '",' + ;
' "Sign": "' + lcSign + '",' + ;
' "Cuit": "20409378472"' + ;
' },' + ;
' "FeCAEReq": {' + ;
' "FeCabReq": {' + ;
' "CantReg": 1, "PtoVta": 1, "CbteTipo": 6' + ;
' },' + ;
' "FeDetReq": {' + ;
' "FECAEDetRequest": {' + ;
' "Concepto": 1, "DocTipo": 99, "DocNro": 0,' + ;
' "CbteDesde": '+ STR(lcNextVoucherNumber) + ', "CbteHasta": '+ STR(lcNextVoucherNumber) + ',' + ;
' "CbteFch": "' + LEFT(TTOC(DATE(), 1), 8) + '",' + ;
' "ImpTotal": 121, "ImpTotConc": 0, "ImpNeto": 100,' + ;
' "ImpOpEx": 0, "ImpIVA": 21, "ImpTrib": 0,' + ;
' "MonId": "PES", "MonCotiz": 1,' + ;
' "CondicionIVAReceptorId": 5,' + ;
' "Iva": {' + ;
' "AlicIva": [{' + ;
' "Id": ' + LTRIM(STR(5)) + ',' + ;
' "BaseImp": ' + LTRIM(STR(100)) + ',' + ;
' "Importe": ' + LTRIM(STR(21)) + ;
' }]' + ;
' }' + ;
' }' + ;
' }' + ;
' }' + ;
' }' + ;
'}'
loHttp.Open("POST", lcInvoiceUrl, .F.)
loHttp.setRequestHeader("Content-Type", "application/json")
loHttp.Send(loInvoiceData)
IF loHttp.Status <> 200
? "Error al crear la factura: " + STR(loHttp.Status)
RETURN
ENDIF
loResponse = loHttp.responseText
loInvoiceResponse = json_decode(loResponse)
? "Invoice: " + loResponse
lcCAE = loInvoiceResponse._fecaesolicitarresult._fedetresp._fecaedetresponse.array[1]._cae
lcCAEVencimiento = loInvoiceResponse._fecaesolicitarresult._fedetresp._fecaedetresponse.array[1]._caefchvto
? "CAE: " + lcCAE
? "Vencimiento CAE: " + lcCAEVencimiento
En loResponse tenemos el CAE y vencimiento correspondientes a la factura que acabamos de crear.
{
...
"CAE": "12345678987654",
"CAEFchVto": "20240327"
...
}
Problemas comunes
Si estás teniendo el error (10016) El número o fecha del comprobante no se corresponde con el próximo a autorizar te recomiendo leer este artículo.
Error (10016) El numero o fecha del comprobante no se corresponde con el proximo a autorizar
Pasos para resolver este error
Si estás teniendo el error (10242) El campo Condición IVA receptor es obligatorio. Consultar método FEParamGetCondicionIvaReceptor te recomiendo leer este artículo.
Error (10242) El campo Condicion IVA receptor es obligatorio
Pasos para resolver este error
Con la autorización creada ya podemos proceder a crear el PDF para presentarle a nuestro cliente. Puedes usar como base esta factura o ticket de ejemplo.
Luego, lo único que nos queda es pasar a modo producción, para más información de cómo hacerlo pueden dirigirse a la documentación de la librería https://docs.afipsdk.com/
Ante cualquier duda o pregunta al respecto, pueden resolverla rápidamente dentro de la Comunidad Afip SDK. Además, puedes unirte para estar al tanto de las novedades y problemas técnicos al usar los servicios de ARCA.
