Consultar constancia de inscripción de ARCA en Visual Basic 6
Con pocas líneas de código
Los datos de inscripción de un contribuyente pueden ser solicitados a través de nuestro sistema, consumiendo los servicios de ARCA.
Esto lo vamos a hacer utilizando Afip SDK, que nos permite conectarnos a los servicios web de ARCA sin complicarnos con el uso de SOAP y la autenticación.
Ademas, vamos a usar https://github.com/VBA-tools/VBA-JSON/blob/master/JsonConverter.bas para trabajar con JSON.
Para esto debemos descargar descargar JsonConverter.bas, y agregarlo a nuestro proyecto.
Elegimos “JsonConverter.bas”
Y agregar la referencia “Microsoft Scripting Runtime”
Elegimos “Microsoft Scripting Runtime”
Obtener la autorización
Lo primero que tenemos hacer es obtener el “Token authorization”, que seria la autorización en ARCA.
Para usar los web services de ARCA, se requiere un certificado digital, con Afip SDK puedes integrarte en modo desarrollo usando el CUIT 20409378472 sin necesidad de obtener un certificado, para poder integrarte lo más rápido posible.
Te dejo este enlace por si luego quieres usar tu propio certificado para desarrollo.
Debemos ejecutar una solicitud POST al endpoint
https://app.afipsdk.com/api/v1/afip/auth
Private Sub GetAuthorization()
Dim objHttp As Object
Dim strResponse As String
Dim strAuthUrl As String
Dim strAuthData As String
Dim dictAuthData As Dictionary
Set objHttp = CreateObject("MSXML2.XMLHTTP")
strAuthUrl = "https://app.afipsdk.com/api/v1/afip/auth"
Set dictAuthData = New Dictionary
dictAuthData.Add "environment", "dev"
dictAuthData.Add "tax_id", "20409378472"
dictAuthData.Add "wsid", "ws_sr_constancia_inscripcion"
strAuthData = JsonConverter.ConvertToJson(dictAuthData)
With objHttp
.Open "POST", strAuthUrl, False
.setRequestHeader "Content-Type", "application/json"
.Send strAuthData
If .Status <> 200 Then
MsgBox "Error en la autorización: " & .Status
MsgBox "Respuesta: " & .responseText
Exit Sub
End If
strResponse = .responseText
End With
Dim objJson As Object
Set objJson = JsonConverter.ParseJson(strResponse)
gstrToken = objJson("token")
gstrSign = objJson("sign")
Debug.Print "Token: " & gstrToken
Debug.Print "Sign: " & gstrSign
End Sub
Aquí tenemos el token y sign que nos dio ARCA para usar el web service. No es necesario que lo guardemos, Afip SDK se encarga de esto por nosotros, debemos solicitarlo antes de cada llamada a los métodos del web service.
Obtenemos los datos
Vamos a obtener los datos del contribuyente con el CUIT 33693450239 (cambiar esto por el CUIT que queramos consultar).
Debemos ejecutar una solicitud POST al endpoint
https://app.afipsdk.com/api/v1/afip/requests
Private Sub GetRegistrationData()
Dim objHttp As Object
Dim strResponse As String
Dim strUrl As String
Dim strData As String
Dim dictData As Dictionary
Set objHttp = CreateObject("MSXML2.XMLHTTP")
strUrl = "https://app.afipsdk.com/api/v1/afip/requests"
Set dictData = New Dictionary
dictData.Add "environment", "dev"
dictData.Add "method", "getPersona_v2"
dictData.Add "wsid", "ws_sr_constancia_inscripcion"
Dim dictParams As Dictionary
Set dictParams = New Dictionary
dictParams.Add "token", gstrToken
dictParams.Add "sign", gstrSign
dictParams.Add "cuitRepresentada", "20409378472"
dictParams.Add "idPersona", 33693450239
dictData.Add "params", dictParams
strData = JsonConverter.ConvertToJson(dictData)
With objHttp
.Open "POST", strUrl, False
.setRequestHeader "Content-Type", "application/json"
.Send strData
If .Status <> 200 Then
MsgBox "Error al obtener los datos: " & .Status
Exit Sub
End If
strResponse = .responseText
End With
Debug.Print "Response: " & strResponse
Dim objJson As Object
Set objJson = JsonConverter.ParseJson(strResponse)
' Aquí puedes acceder a los datos de la constancia de inscripción
End Sub
En la respuesta, nos devolverá los datos de la constancia de inscripción del contribuyente.
{
"apellido": ...,
"nombre": ...,
"domicilioFiscal": ...,
"actividad": ...
}
Problemas comunes
Si estás teniendo el error “No existe persona con ese ID”, se debe a que no todos los CUIT están disponibles en el ambiente de desarrollo. Te recomiendo leer este artículo:
No existe persona con ese Id
Pasos para resolver este error
Con esto ya tenemos los datos del contribuyente. También podes usar el padrón de alcance 13 o el padrón de alcance 10.
Lo único que nos queda es pasar a modo producción para obtener información real de los contribuyentes.
Ante cualquier duda o pregunta al respecto, pueden resolverla rápidamente dentro de la Comunidad Afip SDK. Además, puedes unirte para estar al tanto de las novedades y problemas técnicos al usar los servicios de ARCA.
